Automated WOL.dat generation

I've wrote a handy batch file that painlessly generates the WOL.dat file for you. I borrowed a big chunk of the code from Rob van der Woude of www.robvanderwoude.com

Right now the process writes to c:\WOL.dat, just change that to where you would like the dat file to be stored. This process checks for the computer name in WOL.dat, and removes it's line from the file if it is found. This makes it easy to update a computer's mac address in event of name change or a new NIC. It also pings for the computer before it does makes any changes to the dat file. If the computer isn't found, nothing is changed. Anyways.. have fun with it, hope it helps some of you.

Just make a .bat file with this as its contents, and make a new Hyena tool that calls newBatFile.bat %e%
<div class="ubbcode-block"><div class="ubbcode-header">Quote:</div><div class="ubbcode-body"><div class="ubbcode-block"><div class="ubbcode-header">Code:</div><div class="ubbcode-body ubbcode-pre" ><pre>
@ECHO OFF
:: Check OS version
IF NOT "%OS%"=="Windows_NT" GOTO Syntax

SETLOCAL ENABLEEXTENSIONS

:: Check command line arguments
IF NOT "%~2"=="" GOTO Syntax
ECHO.%1 | FINDSTR /R /C:"[/?*]" >NUL && GOTO Syntax

:: Checks for user variable, if it exists it is set as the computer name, if it doesn't
:: The default is to run the script locally.
IF "%~1"=="" (SET Computer=%ComputerName%) ELSE (SET Computer=%~1)

:: Checks for the computer in the error log, removes if it is found.
:: Comment out or delete the next four lines if you do not want
:: information removed from the log.
find /i /v "%Computer%" < "C:\WOLErrors.log" > "C:\tmp.log"
Ren "C:\WOLErrors.log" WOLErrors.tmp
Ren "C:\tmp.log" WOLErrors.log
del "C:\WOLErrors.tmp"

:: Checks if you are looking up the computer you are on,
:: This skips the ping and NSLookup.
IF /I "%Computer%" == "%ComputerName%" GOTO Lookup

:: Checks that the computer can be pinged within 10ms,
:: increase this if you have a slower network.
:: Also saves the computer's IP Address so the computer
:: name can be confirmed.

:Confirmations
FOR /F "skip=3 tokens=1,3 delims= " %%A IN ('ping %Computer% -n 1 -w 10') DO IF "%%A" == "Reply" (
SET IPAddress=%%B) ELSE IF "%%A"=="Request" (GOTO Timeout)

:: Removes the colon from the end of the retrieved string.
set IPAddress=%IPAddress::=%
ECHO.
ECHO %IPAddress% responded to Ping.

:: Retrieves the computer name using NSLookup and compares
:: it to the supplied computer name. Throws error if the names
:: do not match. This is usefull if the computer has
:: not been turned on long enough for the DNS server to reassign
:: its IP Address.
For /F "tokens=1,2 delims=. " %%A IN ('nslookup %IPAddress%') DO IF "%%A" == "Name:" (Set NSName=%%B)
IF /I "%NSNAME%" NEQ "%Computer%" GOTO Mismatch
ECHO %NSNAME% responded to NSLookup.

:: The actual command is a one-liner, be it a long one.
:: If the batch file is intended for use on local computers only,
:: use IPCONFIG /ALL instead of NBTSTAT -a %Computer%

:Lookup
FOR /F "tokens=*" %%A IN ('NBTSTAT -a %Computer% 2^>NUL ^| FINDSTR /R /I /C:"[0-9A-F][0-9A-F]-*[0-9A-F][0-9A-F]-*[0-9A-F][0-9A-F]-*[0-9A-F][0-9A-F]-*[0-9A-F][0-9A-F]-*[0-9A-F][0-9A-F]"') DO FOR %%B IN (%%A) DO SET MACAddress=%%B
IF "%MACAddress%"=="" GOTO NbstatError

:: Checks for the computer in the .dat file, removes if it is found.
find /i /v "%Computer%" < "C:\WOL.dat" > "C:\tmp.dat"
Ren "C:\WOL.dat" WOL.tmp
Ren "C:\tmp.dat" WOL.dat
del "C:\WOL.tmp"

:: Show result and exit
ECHO.
ECHO.
ECHO ****************************************
ECHO %Computer% %MACAddress%
ECHO %Computer% %MACAddress%>> "C:\WOL.dat"
ECHO.
ECHO WOL.dat has successfully been updated!
ECHO ****************************************
ENDLOCAL & SET MACAddress=%MACAddress%
sleep 1
GOTO End

:Timeout
ECHO.
ECHO //////////////////
Echo Request timed out.
ECHO //////////////////
ECHO.
FOR /F "TOKENS=1* DELIMS= " %%A IN ('DATE/T') DO SET Today=%%B
FOR /F "TOKENS=*" %%A IN ('TIME/T') DO SET Now=%%A
ECHO %Computer% Timed Out on %Today% at %Now%. >> "C:\WOLErrors.log"
sleep 1
GOTO End

:NbstatError
ECHO.
ECHO ////////////////////////
Echo Nbstat could not connect
ECHO ////////////////////////
ECHO.
FOR /F "TOKENS=1* DELIMS= " %%A IN ('DATE/T') DO SET Today=%%B
FOR /F "TOKENS=*" %%A IN ('TIME/T') DO SET Now=%%A
ECHO %Computer% NBSTAT Connection Error on %Today% at %Now%. >> "C:\WOLErrors.log"
sleep 1
GOTO End

:Mismatch
Echo.
ECHO///////////////////////////
ECHO NSLookup returned %NSName%
ECHO///////////////////////////
ECHO.
FOR /F "TOKENS=1* DELIMS= " %%A IN ('DATE/T') DO SET Today=%%B
FOR /F "TOKENS=*" %%A IN ('TIME/T') DO SET Now=%%A
ECHO %Computer% NSLookup Match Error on %Today% at %Now%. %IPAddress% returned %NSName% >> "C:\WOLErrors.log"
sleep 1
GOTO End
:Syntax
ECHO.
ECHO GetMacXP.bat, Version 1.00 for Windows NT 4 and later
ECHO Show the MAC address for any computer in the workgroup or domain
ECHO.
ECHO Usage: GETMACXP [ computer ]
ECHO.
ECHO Where: "computer" is the name of the computer we want to know the
ECHO MAC address of (default is the local computer)
ECHO.
ECHO Written by Rob van der Woude
ECHO http://www.robvanderwoude.com
ECHO Massively changed for use with Hyena by Falyst
pause
IF "%OS%"=="Windows_NT" ENDLOCAL

:End

</pre></div></div></div></div>

edit: added some checks for when nbstat does not find a mac address..

[This message has been edited by Falyst (edited 08-05-2008).]

edit: Added a nslookup check to confirm the computer name and IP correspond with each other. I also made the log only have one entry per computer, to help keep track of which computers need to be updated. Also added checks to work better when updating the same computer the script is running from.

Hopefully there will be no more updates..

[This message has been edited by Falyst (edited 08-06-2008).]

Announcement

Automated WOL.dat generation